initial commit

flake.nix

@@ -0,0 +1,76 @@
+{
+  inputs = {
+    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
+    flake-utils.url = "github:numtide/flake-utils";
+    rust-overlay = {
+      url = "github:oxalica/rust-overlay";
+      inputs.nixpkgs.follows = "nixpkgs";
+    };
+
+    crane.url = "github:ipetkov/crane";
+
+    advisory-db = {
+      url = "github:rustsec/advisory-db";
+      flake = false;
+    };
+  };
+  outputs = {
+    self,
+    nixpkgs,
+    flake-utils,
+    rust-overlay,
+    crane,
+    advisory-db,
+  }:
+    flake-utils.lib.eachDefaultSystem
+    (
+      system: let
+        overlays = [(import rust-overlay)];
+        pkgs = import nixpkgs {
+          inherit system overlays;
+        };
+
+        rustToolchain = pkgs.pkgsBuildHost.rust-bin.fromRustupToolchainFile ./rust-toolchain.toml;
+        craneLib = (crane.mkLib pkgs).overrideToolchain rustToolchain;
+        src = craneLib.cleanCargoSource ./.;
+
+        nativeBuildInputs = with pkgs; [rustToolchain pkg-config];
+        buildInputs = with pkgs; [udev];
+
+        commonArgs = {
+          inherit src buildInputs nativeBuildInputs;
+        };
+
+        cargoArtifacts = craneLib.buildDepsOnly commonArgs;
+        bin = craneLib.buildPackage (commonArgs // {inherit cargoArtifacts;});
+      in
+        with pkgs; {
+          checks = {
+            inherit bin;
+            clippy = craneLib.cargoClippy (commonArgs
+              // {
+                inherit cargoArtifacts;
+                cargoClippyExtraArgs = "--all-targets -- --deny warnings";
+              });
+            coverage = craneLib.cargoTarpaulin (commonArgs // {inherit cargoArtifacts;});
+            fmt = craneLib.cargoFmt {inherit src;};
+            audit = craneLib.cargoAudit {
+              inherit src advisory-db;
+            };
+          };
+
+          packages = {
+            default = bin;
+          };
+
+          apps = rec {
+            default = flake-utils.lib.mkApp {drv = bin;};
+          };
+
+          devShells.default = craneLib.devShell {
+            checks = self.checks.${system};
+            packages = [];
+          };
+        }
+    );
+}